উইকিপিডিয়া:উইকিউপাত্ত কোয়েরি

উইকিউপাত্তে বাংলা উইকিপিডিয়ার নিবন্ধ রক্ষণাবেক্ষণের জন্য SPARQL কোয়েরির তালিকা।

১.

SELECT ?sitelink_label {
  ?wiki_sitelink schema:about ?item; schema:isPartOf <https://bn.wikipedia.org/>; schema:name ?sitelink_label .
  ?item rdfs:label ?label .
  FILTER(LANG(?label) = 'bn') .
  FILTER(false = (LCASE(?sitelink_label) = LCASE(?label)) ) .
  FILTER(false = CONTAINS(?sitelink_label, ')') ) .
} LIMIT 5000

নিবন্ধের নামের সাথে উইকিউপাত্তে দেয়া লেবেলের মিল নেই (লেবেল$\ \neq$ সাইটসংযোগ)

---

২.

SELECT ?sitelink_label WHERE {
   ?wiki_sitelink schema:about ?item; schema:isPartOf <https://bn.wikipedia.org/>; schema:name ?sitelink_label .
  OPTIONAL { ?item rdfs:label ?title . FILTER(lang(?title)="bn") } .
  FILTER(!BOUND(?title))
}

বাংলা উইকির নিবন্ধ যার উইকিউপাত্তের আইটেমে বাংলায় কোন লেভেল নেই

---

৩.

SELECT ?item ?label_bpy WHERE {
  ?item wdt:P31 wd:Q3812392 .
  ?item rdfs:label ?label_bpy filter(lang(?label_bpy) = "bpy") .
  MINUS { ?item rdfs:label ?label_bn filter(lang(?label_bn) = "bn") . }
}
LIMIT 1000

বাংলায় লেবেলহীন বাংলাদেশের ইউনিয়ন

৪.

SELECT DISTINCT ?item
{
	?item wdt:P31 wd:Q3812392 .
	MINUS { ?item schema:description ?description filter (lang(?description) = "bn"). } . 
}

বাংলায় বিবরণহীন বাংলাদেশের ইউনিয়ন

---

৫.

SELECT ?item ?alias {
  ?item ^schema:about/schema:isPartOf/^wdt:P856 wd:Q427715 .
  ?item skos:altLabel ?alias .
  FILTER( LANG( ?alias ) = 'bn' && REGEX( LCASE( STR( ?alias ) ), '[a-z]' ) ) .
} LIMIT 500

উইকিউপাত্তে বাংলায় ভাষার ঘরে "উপনাম ইংরেজিতে দেয়া" যা সরাতে হবে ও উপনাম বাংলায় দিতে হবে

SELECT ?item ?description {
  ?item ^schema:about/schema:isPartOf/^wdt:P856 wd:Q427715 .
  ?item schema:description ?description .
  FILTER( LANG( ?description ) = 'bn' && REGEX( LCASE( STR( ?description ) ), '[a-z]' ) ) .
} LIMIT 500

উইকিউপাত্তে বাংলায় ভাষার ঘরে "বিবরণ ইংরেজিতে দেয়া" যা সরাতে হবে ও বিবরণ বাংলায় দিতে হবে

---

৬.

SELECT ?item {
  BIND( STRLANG( "Bangladeshi chess player", "en" ) AS ?desc ) . # অন্য কিছু খুঁজে বের করতে species of insect পরিবর্তন করতে হবে। যেমন: Bangladeshi cricketer
  ?item schema:description ?desc .
  MINUS {
    ?item schema:description ?description .
    FILTER( LANG( ?description ) = "bn" ) .
  } .
  }

নির্দিষ্ট ইংরেজি বিবরণ আছে কিন্তু বাংলায় কোন বিবরণ নেই এমন আইটেম (উদাহরণ: ইংরেজি বিবরণের ঘরে Bangladeshi chess player লেখা আছে কিন্তু বাংলা বিবরণের ঘরে কোন ধরনের বিবরণ নেই)

যেভাবে উপরের কোয়েরিটি ব্যবহার করে বাংলা বিবরণ যোগ করবেন

• https://tools.wmflabs.org/wikidata-todo/quick_statements.php এ যান। "You need to authorize WiDaR to edit Wikidata on you behalf for this tool to work!"-এর মধ্যে নীল রঙে লেখা WiDaR ক্লিক করুন। আপনার কাছে আপনার পক্ষে সম্পাদনার অনুমতি চাওয়া হবে, অনুমতি দিন।
• http://petscan.wmflabs.org/ এ যান। "Other sources" ট্যাবে ক্লিক করুন। "Input SPARQL query here" ঘরে উপরের কোয়েরিটি দিন ("Bangladeshi chess player" পরিবর্তন করে আপনি অন্য যেকোন বিবরণ বসাতে পারেন)। এরপর Output ট্যাবে ক্লিক করুন। Format হিসেবে PagePile নির্বাচন করুন। এরপর একদম নিচে থাকা "Do it!" ক্লিক করুন।
• "Do it!" ক্লিক করার পর নতুন একটি পাতা আসবে। সেই পাতায় "Other formats: Plain text, wikitext, JSON, JSON (with metadata)"-এর মধ্যে wikitext-এর উপর মাউস নিন, মাউসে ডান ক্লিক করে নতুন ট্যাবে লিঙ্ক খুলুন" (মোটকথা wikitext পাতাটি আপনার ব্রাউজারের নতুন একটি ট্যাবে খুলতে হবে) ক্লিক করুন। এবার সেই পাতায় সকল * [[Q.........]] কপি করে আপনার কম্পিউটারের একটি ফাইল/নোটপ্যাড/অন্য কিছুতে পেস্ট করুন।
• এবার যেখানে * [[Q.........]] পেস্ট করেছেন সেখানে find & replace (খোঁজা ও প্রতিস্থাপন) ব্যবহার করে * [[ কিছু না দিয়ে প্রতিস্থাপন করুন। এরপর ]] নিন্মলিখিত দিয়ে প্রতিস্থাপন করুন: Dbn বাংলাদেশী দাবাড়ু (Dbn এর আগে পরে একটি শূন্যস্থান আছে। তবে এটি কম্পিউটারের space বোতাম দ্বারা না করে ALT ধরে রেখে 09 টিপে দিতে হবে। আর এখানে নমুনা হিসেবে "বাংলাদেশী দাবাড়ু" দেয়া হয়েছে। আপনি যদি অন্য কিছুর জন্য কোয়েরিটি করেন তাহলে "বাংলাদেশী দাবাড়ু"-এর পরিবর্তে তাঁর বিবরণ দিন।) তাহলে সর্বশেষ দেখতে এই রকম হবে

Q2565354	Dbn	বাংলাদেশী দাবাড়ু
Q3347370	Dbn	বাংলাদেশী দাবাড়ু
Q3350646	Dbn	বাংলাদেশী দাবাড়ু
Q421942	Dbn	বাংলাদেশী দাবাড়ু
....
....
....
ইত্যাদি

• এবার সবগুলি (Q2565354 Dbn বাংলাদেশী দাবাড়ু) কপি করুন।
• https://tools.wmflabs.org/wikidata-todo/quick_statements.php এ যান ও খালি ঘরটিতে সবগুলি পেস্ট করুন। এরপর নীল রঙের Do it ক্লিক করুন। ব্যাস, কাজ শেষ। বাকী সব সবকিছু স্বয়ংক্রিয়ভাবে হবে।

---

SELECT ?item ?description {
  ?item ^schema:about/schema:isPartOf/^wdt:P856 wd:Q427715 . # (১)
  ?item schema:description ?description .
  FILTER( LANG( ?description ) = 'bn' && REGEX( STR( ?description ), 'একটি' ) ) .
} LIMIT 100 # (২)

নির্দিষ্ট শব্দের জন্য সন্ধান করা, যেমন: "একটি"

---

সাইটসংযোগ বের করতে

SELECT ?lemma ?item WHERE {
  VALUES ?lemma {
    "ক"@bn # মন্তব্য
  }
  ?sitelink schema:about ?item;
    schema:isPartOf <https://bn.wikipedia.org/>;
    schema:name ?lemma.
}